/*
 *   FILE: 
 *      AZ Demo install
 */

@DefineProject
    @Immediate = 1
    @Name     = "Absolute Zero Demo"
    @Version  = "0.1 Demo"
    @OutDrive = C 
    @Subdir   = "AZ"    
@EndProject

@DefineVars
    @Integer @Continue= 1
@EndVars


@if (@EMMavail <7000k)
  @Display
    Absolute Zero needs at least 7 megs of RAM free.
    ------------------------------------------------
    You do not currently have enogh free memory to run Absolute Zero.
    You may want to consider making a boot disk. Read the "readme.txt"
    file after the installation is done for further instructions.
    Absolute zero will now continue installing...
 
    @Pause
  @EndDisplay
@Endif


@Display
   @Cls

    This program will install @Name on your computer. 
    Simply press the [Esc] key at any time to abort the 
    installation. 

    Press the ENTER key to use the default options.  Otherwise, 
    type your choice and press the ENTER key.

    If you make a mistake while typing, press the BACKSPACE key
    and then retype your choice.

@Pause
@EndDisplay

@GetOutDrive
   @Cls

 @Suppress(0,1)
   



   On which disk drive do you wish to install @Name?

@EndOutDrive


@GetSubdir
   @Cls

    Now you need to specify the disk destination subdirectory.
    This directory is the location on your hard disk where @Name
    files you will be installed.

    The default is now set at @OutDrive @Subdir.

   @Prompt = "Which subdirectory ([Enter] = @Subdir)?"

@EndSubdir

@If (@DirExists("@OutDrive:\\@Subdir"))
   @Display
      
      There's already a directory called @Subdir on disk
      @OutDrive:!  Please choose another name for the
      AZ installation directory, or change the name of the
      @Subdir directory and restart this installation.
      Aborting installation...

      @Pause
      @Exit
    @EndDisplay
@EndIf

@MkDir("@Outdrive:\\@Subdir")

@GetOption @Prompt = "Demo Files"  @LocalWindow(15,35)

     Please select whether you want a full installation, taking appox.
     40Meg of space or a partial installation requiring around 13Meg.

     Full installation installs both the demo of the interface and the
     demo of the main game to your hard drive.  Partial installation
     only installs the main game to your hard drive. You can still run
     the interface but it will run slower from the CDrom-drive. 
     We recommend a full installation.
@Option 1600 = "FULL"
@Option 1700 = "PARTIAL"
@EndOption

@If(1600 [= @option) 
  @if (@DiskFree (@Outdrive) < 40000k)
    @if (@DiskFree (@Outdrive) < 13000k)
       @Display
       
       @Outdrive: drive has only @DiskFree (@Outdrive) bytes free.
       You need 40Meg free to do a full installation of Absolute Zero.
       Free up some space in your hard drive and reinstall Absolute Zero.


          @pause
       @exit
       @EndDisplay
    @else
       @GetOption  @LocalWindow(10,35)

       @Outdrive: drive has only @DiskFree (@Outdrive) bytes free.
       You need 40Meg free to do a full installation of Absolute Zero.
       However, you have enough space for a partial instalation.
       The main game will be installed but the interface will run from 
       the CD-drive and run slower that normal.
       @ClearOption(1600)
       @option  1700 = "Continue with partial installation"
       @option  1600 = "               Exit"
       @EndOption
       @if (1600 [= @option)
          @exit
       @endif
    @endif
 @endif
@endif


@If(1700 [= @option) 
  @if (@DiskFree (@Outdrive) < 13000k)
    @Display


    @Outdrive: drive has only @DiskFree (@Outdrive) bytes free. You need
    13Meg free to install Absolute Zero. Free up some hard drive 
    space and install Absolute Zero again. 
  

          @Pause
    @Exit
    @EndDisplay
  @endif
@endif

@ChDrive(@StartupDrive)
@ChDir("@StartupDir")

@DefineDisk
@label = "Disk 1" 
@BeginLib  Azdemo 
@File *.* @Out @Outdrive:\\@Subdir\\GAME\\*.*  
@EndLib
@File readme.txt @Out @Outdrive:\\@Subdir\\*.* 

@If(1600 [= @option) 
@File azdata\intanim.rsc  @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\*.*
@File azdata\intpctr1.rsc @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\*.*
@File azdata\intpctr2.rsc @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\*.*
@File azdata\intsprt.rsc  @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\*.*
@File azdata\tunanim1.rsc @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\*.*
@File azdata\tunanim2.rsc @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\*.*
@File azdata\map\mapbg.rsc @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\MAP\\*.*
@File azdata\map\mapo2a.rsc  @Out @Outdrive:\\@Subdir\\GAME\\AZDATA\\MAP\\*.*
@Endif
@EndDisk

@if (1600 [= @option)
@Write("@OutDrive:\\@Subdir\\GAME\\CONFIG.FIL","wt","@Outdrive:\\@Subdir\\GAME")
@Endif

@If(1700 [= @option)
@Write("@OutDrive:\\@Subdir\\GAME\\CONFIG.FIL","wt","@StartupDrive:\\AZ\\")
@Endif

@Write("@OutDrive:\\@Subdir\\GAME\\azdemo.bat","wt","@Outdrive:\\@Subdir\\GAME\\azif\n")
@Write("@OutDrive:\\@Subdir\\GAME\\azdemo.bat","at","@Outdrive:\\@Subdir\\GAME\\azgame\n")

@Finish
   @Cls

   @Name is finished installing!  Please take a moment 
   to check the README.TXT file for instructions and comments.

   @Pause

@ChDrive(@Outdrive)
@ChDir("@Subdir")

@execute("edit","readme.txt")

@EndFinish

